Aller au contenu

Paramètres des cookies

Choisissez, par catégorie, les cookies que vous autorisez. Vous pouvez modifier votre choix à tout moment via Paramètres des cookies, en bas de chaque page. Politique de confidentialité

Nécessaires

Toujours activés

Indispensables pour vous connecter, conserver votre panier et mémoriser vos choix. Ils sont toujours activés.

Quels cookies ?
  • weboke_sessie, weboke_klant, weboke_remember: votre session et le maintien de la connexion
  • weboke_basket: votre panier
  • wkBtwIncl: l'affichage des prix TTC ou HT
  • wok_cookies: votre choix concernant les cookies, 12 mois

Mesure quelle publicité mène à une visite ou à une commande, pour que nous ne payions pas des publicités inefficaces.

Quels cookies ?
  • Google Ads via Google Tag Manager (_gcl_au, _gcl_aw), jusqu'à 90 jours
  • OpenAI Ads, publicités dans ChatGPT
  • wok_aff: le partenaire qui vous a orienté vers nous (programme d'affiliation), 60 jours

4,6

Pays et langue

Chaque pays a son propre site, avec les prix et la TVA de ce pays.

Afficher

Comparer deux listes : qui figure dans l'une et pas dans l'autre ?

La liste des membres face aux paiements, les clients de l'an dernier face à ceux de cette année, l'inventaire face à la commande : vous voulez savoir qui figure dans une liste et pas dans l'autre. Trouver et supprimer les clients en double recherche les doublons au sein d'une seule liste ; ici, vous comparez deux listes entre elles.

Prenons pour exemple Bakkerij De Korenaar avec deux feuilles de calcul : Klanten2025 avec les adresses e-mail de l'an dernier en A2:A8, et Klanten2026 avec celles de cette année en A2:A7.

Méthode 1 : une colonne auxiliaire « parti » ou « reste »

Sur la feuille Klanten2025, tapez en B2 :

=SI(NB.SI(Klanten2026!$A$2:$A$7;A2)=0;"parti";"reste")

Recopiez la formule vers le bas jusqu'au dernier client. NB.SI compte combien de fois l'adresse apparaît dans la liste de 2026. Si le résultat est 0, le client est parti. Vous pouvez ensuite filtrer ou trier sur la colonne B (voir Trier et filtrer).

Les signes dollar sont importants : sans eux, la plage de l'autre liste se décale lorsque vous recopiez la formule, et les adresses du haut en sortent par le bas.

Méthode 2 : une liste avec uniquement les différences

Sur une feuille séparée, FILTRE établit en une seule fois la liste de tous les clients partis :

=FILTRE(Klanten2025!A2:A8;NB.SI(Klanten2026!A2:A7;Klanten2025!A2:A8)=0;"aucun départ")

Ici, NB.SI reçoit une liste entière comme deuxième argument et compte simultanément pour chaque adresse de 2025. FILTRE conserve les adresses pour lesquelles ce résultat est 0. Pour trouver les nouveaux clients, inversez les listes :

=FILTRE(Klanten2026!A2:A7;NB.SI(Klanten2025!A2:A8;Klanten2026!A2:A7)=0;"aucun nouveau")

Clients partis et nouveaux clients côte à côte
Clients partis (1) et nouveaux clients (2), chacun avec une seule formule FILTRE

Pour obtenir les personnes qui ne figurent que dans l'une des deux listes, nouvelles ou parties, utilisez :

=UNIQUE(ASSEMB.V(Klanten2025!A2:A8;Klanten2026!A2:A7);;1)

ASSEMB.V place les deux listes l'une sous l'autre. UNIQUE avec un 1 comme troisième argument ne conserve que les valeurs qui apparaissent exactement une fois. Si une adresse figure déjà en double dans une même liste, rendez d'abord cette liste unique : =UNIQUE(ASSEMB.V(UNIQUE(Klanten2025!A2:A8);UNIQUE(Klanten2026!A2:A7));;1).

Méthode 3 : des couleurs plutôt que des listes

  1. Sur la feuille Klanten2025, sélectionnez les adresses, A2:A8.
  2. Dans l'onglet Accueil, choisissez Mise en forme conditionnelle, Nouvelle règle, type Formule.
  3. Tapez =NB.SI(Klanten2026!$A$2:$A$7;$A2)=0, choisissez une couleur de remplissage et cliquez sur OK.

Une référence à une autre feuille dans une règle de mise en forme fonctionne sans problème dans Euro-Office ; dans les anciennes versions d'Excel, il fallait passer par un nom défini.

Clients partis mis en couleur
Les adresses qui n'apparaissent plus en 2026 sont colorées en orange ; la colonne B indique « parti » ou « reste »

Pièges à éviter

  • Espaces : « info@dekorenaar.nl » suivi d'un espace est, pour le tableur, une autre adresse. Supprimez d'abord les espaces avec SUPPRESPACE dans une colonne auxiliaire.
  • Cellules vides : dans une plage, elles comptent aussi comme une valeur. Ne prenez donc que les lignes contenant des données, ou écartez les cellules vides avec <>"".
  • Nombres face à du texte : si vous comparez des numéros de client et que le numéro figure sous forme de texte dans une liste (aligné à gauche dans la cellule) et sous forme de nombre dans l'autre, ils ne se retrouvent pas. Voir RECHERCHEV renvoie #N/A : comment résoudre le problème.
  • Ne tapez pas VRAI sans parenthèses comme troisième argument de UNIQUE ; Euro-Office ne reconnaît que TRUE, VRAI() ou 1 (voir Reprendre des formules d'Excel : noms de fonctions français et le point-virgule).

Un instant…

Configurez vos domaines

Pour chaque domaine, réglez les serveurs de noms, l'association à votre hébergement et le futur titulaire.

Chargement de vos domaines…